in

How to work Mouse Button, Controlling by Arduino

https://mrtechies.com/wp-content/uploads/2020/08/2020-19.jpg

Mouse நூலகத்தைப் பயன்படுத்தி, ஒரு கணினியின் திரை cursor ஒரு  Arduino Leonardo, Micro அல்லது Due மூலம் கட்டுப்படுத்தலாம்.

இந்த குறிப்பிட்ட எடுத்துக்காட்டு திரை கர்சரை நகர்த்த ஐந்து புஷ்பட்டன்களைப் பயன்படுத்துகிறது. பொத்தான்கள் நான்கு திசை (மேல், கீழ், இடது, வலது) மற்றும் ஒரு இடது சுட்டி கிளிக் ஆகும். Arduino இலிருந்து கர்சர் இயக்கம் எப்போதும் உறவினர். ஒவ்வொரு முறையும் ஒரு உள்ளீட்டைப் படிக்கும்போது, ​​கர்சரின் நிலை அதன் தற்போதைய நிலைக்கு ஒப்பிடும்போது புதுப்பிக்கப்படும்.

திசை பொத்தான்களில் ஒன்றை அழுத்தும் போதெல்லாம், அர்டுயினோ சுட்டியை நகர்த்தி, ஒரு உயர் உள்ளீட்டை 5 வரம்பிற்கு பொருத்தமான திசையில் வரைபடமாக்கும்.

ஐந்தாவது பொத்தான் சுட்டியில் இருந்து இடது கிளிக் கட்டுப்படுத்துவதாகும். பொத்தானை வெளியிடும் போது, ​​கணினி நிகழ்வை அங்கீகரிக்கும்.

Components Required

உங்களுக்கு பின்வரும் கூறுகள் தேவைப்படும்

  • 1 × Breadboard
  • 1 × Arduino Leonardo, Micro or Due board
  • 5 × 10k ohm resistor
  • 5 × momentary pushbuttons

செயல்முறை

சுற்று வரைபடத்தைப் பின்பற்றி, கீழே உள்ள படத்தில் காட்டப்பட்டுள்ளபடி பிரெட்போர்டில் உள்ள கூறுகளை இணைக்கவும்.

Sketch


உங்கள் கணினியில் Arduino IDE மென்பொருளைத் திறக்கவும். Arduino மொழியில் குறியீட்டு உங்கள் சுற்று கட்டுப்படுத்தும். புதியதைக் கிளிக் செய்வதன் மூலம் புதிய ஸ்கெட்ச் கோப்பைத் திறக்கவும்.

இந்த எடுத்துக்காட்டுக்கு, நீங்கள் Arduino IDE 1.6.7 ஐப் பயன்படுத்த வேண்டும்

Arduino Code

/*
   Button Mouse Control
   For Leonardo and Due boards only .Controls the mouse from 
   five pushbuttons on an Arduino Leonardo, Micro or Due.
   Hardware:
   * 5 pushbuttons attached to D2, D3, D4, D5, D6
   The mouse movement is always relative. This sketch reads
   four pushbuttons, and uses them to set the movement of the mouse.
   WARNING: When you use the Mouse.move() command, the Arduino takes
   over your mouse! Make sure you have control before you use the mouse commands.
*/

#include "Mouse.h"
// set pin numbers for the five buttons:
const int upButton = 2;
const int downButton = 3;
const int leftButton = 4;
const int rightButton = 5;
const int mouseButton = 6;
int range = 5; // output range of X or Y movement; affects movement speed
int responseDelay = 10; // response delay of the mouse, in ms

void setup() {
   // initialize the buttons' inputs:
   pinMode(upButton, INPUT);
   pinMode(downButton, INPUT);
   pinMode(leftButton, INPUT);
   pinMode(rightButton, INPUT);
   pinMode(mouseButton, INPUT);
   // initialize mouse control:
   Mouse.begin();
}

void loop() {
   // read the buttons:
   int upState = digitalRead(upButton);
   int downState = digitalRead(downButton);
   int rightState = digitalRead(rightButton);
   int leftState = digitalRead(leftButton);
   int clickState = digitalRead(mouseButton);
   // calculate the movement distance based on the button states:
   int xDistance = (leftState - rightState) * range;
   int yDistance = (upState - downState) * range;
   // if X or Y is non-zero, move:
   if ((xDistance != 0) || (yDistance != 0)) {
      Mouse.move(xDistance, yDistance, 0);
   }

   // if the mouse button is pressed:
   if (clickState == HIGH) {
      // if the mouse is not pressed, press it:
      if (!Mouse.isPressed(MOUSE_LEFT)) {
         Mouse.press(MOUSE_LEFT);
      }
   } else {                           // else the mouse button is not pressed:
      // if the mouse is pressed, release it:
      if (Mouse.isPressed(MOUSE_LEFT)) {
         Mouse.release(MOUSE_LEFT);
      }
   }
   // a delay so the mouse does not move too fast:
   delay(responseDelay);
}


கவனிக்க வேண்டிய குறியீடு

micro-USB cable மூலம் உங்கள் போர்டை (board) உங்கள் கணினியுடன் இணைக்கவும். பொத்தான்கள் பின்ஸ் 2 முதல் 6 வரை டிஜிட்டல் உள்ளீடுகளுடன் இணைக்கப்பட்டுள்ளன. நீங்கள் 10k pull-down மின்தடைகளைப் பயன்படுத்துகிறீர்கள் என்பதை உறுதிப்படுத்திக் கொள்ளுங்கள்.

Written by Rifdhy Ahmed

Leave a Reply

Your email address will not be published. Required fields are marked *

This site uses Akismet to reduce spam. Learn how your comment data is processed.

GIPHY App Key not set. Please check settings

what is the Keyboard Message in Arduino

How to work Keyboard Serial with Arduino